/*
    irf_describe.dlg

*!  VERSION 1.0.0  14jul2004

*/

VERSION 8.0

INCLUDE _std_medium
INCLUDE header
HELP hlp1, view("help irf_describe")
RESET res1

DIALOG main, label("irf describe - Describe an IRF file") tabtitle("Main")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_irfset

  GROUPBOX gb_group1         _lft      _ms       _iwd      _ht6,
  RADIO    rb_default        _ilft     _ss       _ibwd     ., 		///
  		first							///
		onclickon(main.fi_using.disable)			///
		label("Describe active IRF results")
  RADIO    rb_using          @         _ss       @         ., 		///
  		last							///
		onclickon(main.fi_using.enable)				///
		label("Describe results from IRF file: (without making active)")

  FILE     fi_using          _indent2  _ss       _inwd     .,		///
		label("Browse...")					///
		error("Describe results from IRF file")			///
		defext(vrf)						///
		option(using) filter("IRF Files (*.irf)|*.irf|All Files (*.*)|*.*")

  GROUPBOX gb_group2         _lft      _xls      _iwd      _ht4,
  RADIO    rb_nodetail       _ilft     _ss       _ibwd     .,		///
  		first							///
		option(NONE)						///
		label("Show the IRF names and variable order")
  RADIO    rb_detail         @         _ss       @         ., 		///
  		last							///
		option(detail)						///
		label("Show additional details")

  CHECKBOX ck_variable       _lft      _xls      _iwd      .,		///
		option(variables)					///
		label("Show the underlying structure of the IRF dataset")
END


PROGRAM command
BEGIN
	put "irf describe "
	// not doing irf_resultslist -- instead just get all of them
	beginoptions
		// not doing set() option since have set IRF button at top
		if main.rb_using {
			require main.fi_using
			optionarg /oquoted main.fi_using
		}
		option radio(main rb_nodetail rb_detail)
		option main.ck_variable
	endoptions
END
