/*
  Include file for yaxis tab. Used with easy graph box dialog

  VERSION 1.0.1  31mar2005

*/

DIALOG eyaxis_box, label("") tabtitle("Y-Axis")
BEGIN
  GROUPBOX gb_yaxis    _lft        _top      _comb4_1    _ht11h,
  TEXT     tx_ytitle   _ilft       _ms       _txwd       .,		///
 	label("Title:") right
  EDIT     ed_ytitle   _txsep      @         _vllwd      .,		///
 	label("Y-Title")
  TEXT     tx_ysize    _ilft       _ms       _txwd       .,		///
  	label("Title size:") right
  COMBOBOX cb_ysize    _txsep      @         _cbwd       ., 		///
  	label("Y-Axis Size")						///
  	dropdownlist contents(textsizes)				///
  	option(size)
  TEXT     tx_yrule    _ilft       _xxls     _txwd       .,		///
 	label("Tick rule:") right
  EDIT     ed_yrule    _txsep      @         _vllwdmbu   .,		///
 	label("Y-Tick rule")
  BUTTON   bu_yrule    _vllwdbusep @         _btwd       .,		///
  	label("?")							///
  	onpush(view help major_tick_rule##|_new)
END

PROGRAM eyaxis_box_ytitle_opts
BEGIN
	beginoptions
		optionarg eyaxis_box.cb_ysize
	endoptions
END

PROGRAM eyaxis_box_output
BEGIN
  if eyaxis_box.ed_ytitle | eyaxis_box.cb_ysize {
  	put " " "ytitle("
  	put eyaxis_box.ed_ytitle
  	put /program eyaxis_box_ytitle_opts
  	put ") "
  }
  if eyaxis_box.ed_yrule {
  	put " " "ylabel("
  	put eyaxis_box.ed_yrule
  	put ") "
  }
END
