/*
	mi_varying

*!  VERSION 1.0.1  03jul2009

*/

VERSION 11.0

INCLUDE _std_msmall
DEFINE _dlght 125 
INCLUDE header
HELP hlp1, view("help mi_varying")
RESET res1

DIALOG main, tabtitle("Main")						///
	label("mi varying - Identify variables that vary across imputations")
	
BEGIN
  RADIO rb_vars		_lft	_top	_iwd	., first		///
	onclickon("script main_rb_vars_on")				///
	label("List all variables")
  RADIO rb_unreg	@	_ss	_iwd	., last			///
	onclickon("script main_rb_unreg_on")				///
	option(unregistered)						///
	label("List only unregistered variables")
  TEXT tx_vars		@	_ls	_iwd	.,			///
	label("Variables: (leave empty for all)")

  VARLIST vl_vars	@	_ss	_iwd	.,			///
	label("Variables")
END

SCRIPT main_rb_vars_on
BEGIN
	main.tx_vars.show
	main.vl_vars.show
END

SCRIPT main_rb_unreg_on
BEGIN
	main.tx_vars.hide
	main.vl_vars.hide
END

PROGRAM command
BEGIN
	put "mi varying "
	varlist [main.vl_vars]
	beginoptions
		option main.rb_unreg
	endoptions
END
